Script with RUNALLOCATION
*SELECT(%CC%,"[ID]",COST_CENTER,"[ID]<>CC_NONE AND [CALC]=N")
*XDIM_MEMBERSET PERIOD = %PERIOD_SET%
*XDIM_MEMBERSET VERSION = %VERSION_SET%
*XDIM_MEMBERSET ACCOUNT = PERCENTAGE_HC_RATE_INCREASE
*XDIM_MEMBERSET FLOW = F_NONE
*XDIM_MEMBERSET CURRENCY = LC
*XDIM_MEMBERSET AUDIT_TRAIL = CC_PLAN_INPUT
*XDIM_MEMBERSET COMPANY_CODE = COMPANY_NONE
*XDIM_MEMBERSET SEGMENT = SEG_NONE
*XDIM_MEMBERSET PROFIT_CENTER = PC_NONE
*XDIM_MEMBERSET FUNCTIONAL_AREA = FA_NONE
*XDIM_MEMBERSET INTERNAL_ORDER = IO_NONE
*XDIM_MEMBERSET PARTNER_CC = PCC_NONE
//Clear temporary values for safety
*XDIM_MEMBERSET COST_CENTER = %CC%
*WHEN COST_CENTER
*IS *
*REC(EXPRESSION=0)
*ENDWHEN
//Copy temporary using RUNALLOCATION to All COST_CENTER members with COMPANY_NONE,SEG_NONE,PC_NONE,FA_NONE,IO_NONE,PCC_NONE
*XDIM_MEMBERSET COST_CENTER = CC_NONE
*RUNALLOCATION
*FACTOR=1
*DIM COST_CENTER WHAT=CC_NONE;WHERE=%CC%
*ENDALLOCATION
//Copy to required COMPANY_CODE,SEGMENT,PROFIT_CENTER,FUNCTIONAL_AREA
//Scope has to be restored after *ENDALLOCATION
*XDIM_MEMBERSET ACCOUNT = PERCENTAGE_HC_RATE_INCREASE
*XDIM_MEMBERSET FLOW = F_NONE
*XDIM_MEMBERSET CURRENCY = LC
*XDIM_MEMBERSET AUDIT_TRAIL = CC_PLAN_INPUT
*XDIM_MEMBERSET COMPANY_CODE = COMPANY_NONE
*XDIM_MEMBERSET SEGMENT = SEG_NONE
*XDIM_MEMBERSET PROFIT_CENTER = PC_NONE
*XDIM_MEMBERSET FUNCTIONAL_AREA = FA_NONE
*XDIM_MEMBERSET INTERNAL_ORDER = IO_NONE
*XDIM_MEMBERSET PARTNER_CC = PCC_NONE
*XDIM_MEMBERSET COST_CENTER = %CC%
*WHEN COST_CENTER
*IS *
*REC(EXPRESSION=%VALUE%,COMPANY_CODE=COST_CENTER.COMP_CODE, SEGMENT=COST_CENTER.SEGMENT, PROFIT_CENTER=COST_CENTER.PROFIT_CENTER, FUNCTIONAL_AREA=COST_CENTER.FUNCTIONAL_AREA)
*ENDWHEN
//Clear temporary
*WHEN COST_CENTER
*IS *
*REC(EXPRESSION=0)
*ENDWHEN
Vadim